dnl Process this file with autoconf to produce a configure script.

AC_INIT(README)

GXSNMP_MAJOR_VERSION=0
GXSNMP_MINOR_VERSION=0
GXSNMP_MICRO_VERSION=16
GXSNMP_VERSION=$GXSNMP_MAJOR_VERSION.$GXSNMP_MINOR_VERSION.$GXSNMP_MICRO_VERSION

# For automake

VERSION=$GXSNMP_VERSION
PACKAGE=gxsnmp

AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
AM_CONFIG_HEADER(include/config.h)

AM_ACLOCAL_INCLUDE(macros)

####
AC_ISC_POSIX
AC_PROG_CC
AC_PROG_CXX
AC_PROG_INSTALL
AC_PROG_MAKE_SET
AM_PROG_LIBTOOL

AC_CHECK_FUNCS(getopt_long,,
	need_getopt=yes)
AM_CONDITIONAL(WANT_GETOPT, test x$need_getopt = xyes)

GNOME_INIT_HOOK([ client=yes ], continue)

AM_PATH_GLIB(1.2.0)

dnl ***** Internationalization ****
ALL_LINGUAS=
AM_GNOME_GETTEXT

dnl ***** Check for gcc and enable gcc features *****
if test "x${GCC}" = "xyes"
then
   CFLAGS="$CFLAGS -Wall -Wshadow"
   AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
        AC_TRY_RUN([
int main(void) {
  static int Array[[3]];
  unsigned int B = 3;
  int i;
  for(i=0; i<B; i++) Array[[i]] = i - 3;
  exit( Array[[1]] != -2 );
}],
    ac_cv_c_gcc_strength_bug="no",
    ac_cv_c_gcc_strength_bug="yes",
    ac_cv_c_gcc_strength_bug="yes") )
  if test "$ac_cv_c_gcc_strength_bug" = "yes"
   then
    CFLAGS="$CFLAGS -fno-strength-reduce"
  fi
fi
dnl **** If using gcc make a neat pipeline of the compiler componets ****
if test "x${GCC}" = "xyes"
then
   CFLAGS="$CFLAGS -pipe"
fi

dnl *********************************
dnl Check for libsmi
dnl *********************************
SMI_LIB=""
AC_CHECK_LIB(smi,smiInit,SMI_LIB="-lsmi", [
echo "ERROR: gxsnmp needs the SMI Library."
echo "At least version 0.2 is required."
echo "You can obtain it from:"
echo "http://www.ibr.cs.tu-bs.de/projects/libsmi/"
echo "ftp://ftp.ibr.cs.tu-bs.de/pub/local/libsmi/"
AC_MSG_ERROR([Fatal Error: no libsmi detected.])])
AC_SUBST(SMI_LIB)
dnl ******************************
dnl Check for Bonobo
dnl ******************************
AC_MSG_CHECKING(for Bonobo >= 0.18)
if gnome-config --libs bonobo > /dev/null 2>&1; then
        vers=`gnome-config --modversion bonobo | sed -e "s/bonobo-//" | \
		awk 'BEGIN { FS = "."; } { printf "%d", $1 * 1000 + $2;}'`
        if test "$vers" -ge 18; then 
		bonobo_ok=true
	else
		bonobo_ok=false
	fi
else
	bonobo_ok=false
fi

if $bonobo_ok; then
        AC_MSG_RESULT($vers found)
else
        AC_MSG_ERROR(Bonobo 0.18 is required to compile GxSNMP)
fi

dnl ******************************
dnl LibGlade checking
dnl ******************************
AC_MSG_CHECKING(for Glade libraries)
if gnome-config --libs libglade > /dev/null 2>&1; then
    AC_MSG_RESULT(found)
else
    AC_MSG_ERROR(Did not find libGlade installed)
fi

BONOBO_GNOME_LIBS="`gnome-config --libs bonobox_print libglade gdk_pixbuf gnomecanvaspixbuf gnomeui`"
BONOBO_GNOME_CFLAGS="`gnome-config --cflags bonobox_print libglade gdk_pixbuf gnomecanvaspixbuf gnomeui `"
AC_SUBST(BONOBO_GNOME_LIBS)
AC_SUBST(BONOBO_GNOME_CFLAGS)
dnl ******************************
dnl Whether to use OAF
dnl ******************************

AC_MSG_CHECKING(if Bonobo uses OAF)
if ( gnome-config --libs bonobo | grep oaf ) > /dev/null 2>&1 ; then
        enable_oaf="yes"
else
        enable_oaf="no"
fi

AC_MSG_RESULT("$enable_oaf")

if test "x$enable_oaf" = "xyes"; then
        AC_PATH_PROG(OAF_CONFIG,oaf-config,no)
        if test x$OAF_CONFIG = xno; then
                AC_MSG_ERROR("You enabled OAF support but oaf-config was not found")
        else
                OAF_LIBS=`$OAF_CONFIG --libs`
                OAF_CFLAGS=`$OAF_CONFIG --cflags`
                GNORBA_LIBNAME=
        fi
else
        OAF_LIBS=
        OAF_CFLAGS=
        GNORBA_LIBNAME=gnorba
fi

AC_SUBST(OAF_LIBS)
AC_SUBST(OAF_CFLAGS)
AM_CONDITIONAL(USING_OAF, test "x$enable_oaf" = "xyes")

if test "x$enable_oaf" = "xyes"; then
        AC_DEFINE(USING_OAF)
        BONOBO_GNOME_LIBS="`oaf-config --libs` $BONOBO_GNOME_LIBS"
        BONOBO_GNOME_CFLAGS="`oaf-config --cflags ` $BONOBO_GNOME_CFLAGS"
fi

dnl Checks for library functions.
dnl Checks for available network protocols.
dnl Always assume IPv4 is available. This might change sometime...
AC_DEFINE(HAVE_INET)

AC_OUTPUT([
Makefile
include/Makefile
include/database/Makefile
lib/Makefile
client/Makefile
client/components/Makefile
client/components/mib-browser/Makefile
client/components/snmp-forms/Makefile
server/Makefile
server/database/Makefile
server/database/tables/Makefile
support/Makefile
data/Makefile
data/pixmaps/Makefile
docs/Makefile
po/Makefile.in
intl/Makefile])